3C2440啟動代碼注釋

發布時間：2009-11-24 10:35 發布者：李寬

關鍵詞：代碼 , 注釋

快一個月了,終于分析完了S3C2440的啟動代碼,由于在同時分析S3C2400啟動代碼和BT代碼,并且還經常折騰我的博客,所以進展慢了些,現在把分析結果貼出來,前面的定義做了詳細的分析,后面各個模塊的功能也做了注釋,但是各個模塊怎么實現的,我也沒有完全弄明白,還有學習中,有些也是參考了網上的注釋,有錯誤,疑問的都可以給我留言.

;GET和INCLUDE功能相同
;功能：引進一個被編譯過的文件。
GET option.inc
GET memcfg.inc
GET 2440addr.inc

;EQU為程序中的常量、標號等定義一個等效的字符名稱
;定義SDRAM工作在Refresh模式，SDRAM有兩種刷新方式：autorefresh和selfrefresh，前者是在其使用過程當中每隔一段時間發出刷新指令，SDRAM刷新一行，self refresh是在省電模式時使用
BIT_SELFREFRESH EQU (1<<22)

;系統的工作模式設定,共七種工作模式
USERMODE EQU    0x10
FIQMODE    EQU    0x11
IRQMODE    EQU    0x12
SVCMODE    EQU    0x13
ABORTMODE EQU    0x17
UNDEFMODE EQU    0x1b
MODEMASK EQU    0x1f
NOINT    EQU    0xc0

;系統的堆�？臻g設定
UserStack EQU (_STACK_BASEADDRESS-0x3800) ;0x33ff4800 ~
SVCStack EQU (_STACK_BASEADDRESS-0x2800) ;0x33ff5800 ~
UndefStack EQU (_STACK_BASEADDRESS-0x2400) ;0x33ff5c00 ~
AbortStack EQU (_STACK_BASEADDRESS-0x2000) ;0x33ff6000 ~
IRQStack EQU (_STACK_BASEADDRESS-0x1000) ;0x33ff7000 ~
FIQStack EQU (_STACK_BASEADDRESS-0x0) ;0x33ff8000 ~

;這一段是為了統一處理器工作狀態和軟件編譯方式（16位編譯環境使用tasm.exe編譯）
;arm有兩種工作狀態:32位，該狀態執行字對準的arm指令；16位，該狀態執行半字對準的Thumb指令
;不同的工作狀態，編譯器編譯方式也不同
GBLL THUMBCODE ;定義一個全局變量
[ {CONFIG} = 16    ; CONFIG為ADS定義的內部變量
THUMBCODE SETL  {TRUE} ;SETA 指令用于設置局部或全局算術變量的值,SETL 指令用于設置局部或全局邏輯變量的值,SETS 指令用于設置局部或全局字符串變量的值
      CODE32          ;工作在arm狀態
      |
THUMBCODE SETL  {FALSE}  ;[ | ] 是ARM匯編控制偽指令，就是 IF ELSE ENDIF，簡寫成 [ | ]
]

      MACRO          ;宏定義
MOV_PC_LR
      [ THUMBCODE
      bx lr
      |
      mov pc,lr
      ]
MEND

      MACRO
MOVEQ_PC_LR
      [ THUMBCODE
      bxeq lr
      |
      moveq pc,lr
      ]
MEND

;這段程序用于把中斷服務程序的首地址裝載到pc中，有人稱之為“加載程序”。
;本初始化程序定義了一個數據區（在文件最后），存放相應中斷服務程序的首地址。每個字空間都有一個標號，以Handle***命名。

      MACRO
$HandlerLabel HANDLER $HandleLabel

$HandlerLabel
sub sp,sp,#4 ;用來存儲PC地址
stmfd sp!,{r0} ;把將要使用的r0寄存器入棧
ldr    r0,=$HandleLabel;給寄存器r0賦值
ldr    r0,[r0]    ;給寄存器r0賦值,將r0的地址放入r0
str    r0,[sp,#4]    ;將對應的中斷函數首地址入棧
ldmfd sp!,{r0,pc}    ;彈出工作寄存器ro和PC,也就完成了到ISR的跳轉

MEND

IMPORT  |Image$$RO$$Limit|  ; 表示RO區末地址后面的地址，即RW數據源的起始地址
IMPORT  |Image$$RW$$Base| ; RW區在RAM里的執行區起始地址，也就是編譯器選項RW_Base指定的地址。
IMPORT  |Image$$ZI$$Base| ; ZI區在RAM里面的起始地址
IMPORT  |Image$$ZI$$Limit|  ; ZI區在RAM里面的結束地址后面的一個地址

IMPORT Main

AREA Init,CODE,READONLY  ;聲明一個代碼段

ENTRY

;下面的代碼是小端和大端的轉換
  ;條件編譯，在編譯成機器碼前就設定好
ASSERT

EF:ENDIAN_CHANGE ;判斷ENDIAN_CHANGE是否定義
[ ENDIAN_CHANGE
ASSERT

EF:ENTRY_BUS_WIDTH ;如果已經定義了ENDIAN_CHANGE,判斷ENTRY_BUS_WIDTH是否定義
      [ ENTRY_BUS_WIDTH=32          ;判斷是不是為32
      b ChangeBigEndian       ;DCD 0xea000007
      ]

      [ ENTRY_BUS_WIDTH=16
      andeq r14,r7,r0,lsl #20 ;DCD 0x0007ea00
      ]

      [ ENTRY_BUS_WIDTH=8
      streq r0,[r0,-r10,ror #1] ;DCD 0x070000ea
      ]
|
      b ResetHandler
]
b HandlerUndef ;轉跳到Undefined mode程序入口
b HandlerSWI ;轉跳到SWI 中斷程序入口
b HandlerPabort ;轉跳到PAbort(指令異常)程序入口
b HandlerDabort ;轉跳到DAbort(數據異常)程序入口
b .       ;保留
b HandlerIRQ ;轉跳到IRQ 中斷程序入口
b HandlerFIQ ;轉跳到FIQ 中斷程序入口

;@0x20
b EnterPWDN ; Must be @0x20.
;通過設置CP15的C1的位7，設置存儲格式為Bigendian，三種總線方式
ChangeBigEndian    ;下面是改變大小端的程序,這里采用直接定義機器碼的方式
;@0x24
[ ENTRY_BUS_WIDTH=32
      DCD 0xee110f10 ;0xee110f10 => mrc p15,0,r0,c1,c0,0
      DCD 0xe3800080 ;0xe3800080 => orr r0,r0,#0x80;  //Big-endian
      DCD 0xee010f10 ;0xee010f10 => mcr p15,0,r0,c1,c0,0
]
[ ENTRY_BUS_WIDTH=16
      DCD 0x0f10ee11
      DCD 0x0080e380
      DCD 0x0f10ee01
]
[ ENTRY_BUS_WIDTH=8
      DCD 0x100f11ee
      DCD 0x800080e3
      DCD 0x100f01ee
]
DCD 0xffffffff
DCD 0xffffffff
DCD 0xffffffff
DCD 0xffffffff
DCD 0xffffffff
b ResetHandler

;掉電模式
;SDRAM自動刷新.
;進入PWDN
EnterPWDN
mov r2,r0       ;r2=rCLKCON
tst r0,#0x8       ;測試是否是SLEEP mode?
bne ENTER_SLEEP

ENTER_STOP          ;進入PWDN后如果不是sleep則進入stop
ldr r0,=REFRESH
ldr r3,[r0]       ;r3=rREFRESH
mov r1, r3
orr r1, r1, #BIT_SELFREFRESH
str r1, [r0]       ;使SDRAM自動刷新

mov r1,#16          ;等待刷新，也可能不需要
0 subs r1,r1,#1
bne %B0

ldr r0,=CLKCON       ;進入STOP mode.
str r2,[r0]

mov r1,#32
0 subs r1,r1,#1
bne %B0
         ; 進入SLEEP mode, 只有通過喚醒復位.

ldr r0,=REFRESH ;退出SDRAM self refresh mode.
str r3,[r0]

MOV_PC_LR

ENTER_SLEEP
;rGSTATUS3有一個返回地址

ldr r0,=REFRESH
ldr r1,[r0]       ;r1=rREFRESH
orr r1, r1, #BIT_SELFREFRESH
str r1, [r0]       ;啟用SDRAM self-refresh

mov r1,#16          ;等待self-refresh,也可能不需要.
0 subs r1,r1,#1
bne %B0

ldr r1,=MISCCR
ldr r0,[r1]
orr r0,r0,#(7<<17)  ;設置SCLK0=0, SCLK1=0, SCKE=0.
str r0,[r1]

ldr r0,=CLKCON       ;進入sleep mode
str r2,[r0]

b .          ;CPU不工作.

WAKEUP_SLEEP
;Release SCLKn after wake-up from the SLEEP mode.
ldr r1,=MISCCR
ldr r0,[r1]
bic r0,r0,#(7<<17)  ;SCLK0:0->SCLK, SCLK1:0->SCLK, SCKE:0->=SCKE.
str r0,[r1]

;設置存儲控制寄存器
   ldr r0,=SMRDATA
ldr r1,=BWSCON ;總線寬度和等待控制寄存器
add r2, r0, #52 ;SMRDATA的結束地址
0
ldr r3, [r0], #4
str r3, [r1], #4
cmp r2, r0
bne %B0
;數據在以SMRDATA為起始的存儲區
mov r1,#256
0 subs r1,r1,#1 ;1) wait until the SelfRefresh is released.
bne %B0

ldr r1,=GSTATUS3    ;GSTATUS3 has the start address just after SLEEP wake-up
ldr r0,[r1]

mov pc,r0

;異常中斷宏調用
LTORG
HandlerFIQ    HANDLER HandleFIQ
HandlerIRQ    HANDLER HandleIRQ
HandlerUndef HANDLER HandleUndef
HandlerSWI    HANDLER HandleSWI
HandlerDabort HANDLER HandleDabort
HandlerPabort HANDLER HandlePabort

IsrIRQ
sub sp,sp,#4    ;reserved for PC
stmfd sp!,{r8-r9}

ldr r9,=INTOFFSET
ldr r9,[r9]
ldr r8,=HandleEINT0
add r8,r8,r9,lsl #2
ldr r8,[r8]
str r8,[sp,#8]
ldmfd sp!,{r8-r9,pc}

;=======
; ENTRY
;板子上電和復位后,程序開始從位于0x00執行b ResetHandler,程序跳轉到這里執行
;=======
ResetHandler
ldr r0,=WTCON    ;屏蔽看門狗
ldr r1,=0x0
str r1,[r0]

ldr r0,=INTMSK
ldr r1,=0xffffffff  ;屏蔽所有的中斷
str r1,[r0]

ldr r0,=INTSUBMSK
ldr r1,=0x3ff       ;屏蔽所有的子中斷
str r1,[r0]

[ {FALSE}
; rGPFDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);
; Led_Display
ldr r0,=GPFCON
ldr r1,=0x5500
str r1,[r0]
ldr r0,=GPFDAT
ldr r1,=0x10
str r1,[r0]
]

;根據工作頻率設置pll
ldr r0,=LOCKTIME
ldr r1,=0xffffff
str r1,[r0]

[ PLL_ON_START
; 為2440添加時鐘設備.
; 設置Fclk:Hclk

clk
ldr r0,=CLKDIVN
ldr r1,=CLKDIV_VAL       ; 0=1:1:1, 1=1:1:2, 2=1:2:2, 3=1:2:4, 4=1:4:4, 5=1:4:8, 6=1:3:3, 7=1:3:6.
str r1,[r0]

;Configure UPLL
ldr r0,=UPLLCON
ldr r1,=((U_MDIV<<12)+(U_PDIV<<4)+U_SDIV)  ;設定系統主時鐘頻率

str r1,[r0]

nop ; Caution: After UPLL setting, at least 7-clocks delay must be inserted for setting hardware be completed.
nop
nop
nop
nop
nop
nop
;配置MPLL
ldr r0,=MPLLCON
ldr r1,=((M_MDIV<<12)+(M_PDIV<<4)+M_SDIV)
str r1,[r0]
]

  ;檢查啟動是從休眠模式喚醒.
ldr r1,=GSTATUS2
ldr r0,[r1]
tst r0,#0x2
;是從休眠模式喚醒,跳轉到SLEEP_WAKEUP handler.
bne WAKEUP_SLEEP

EXPORT StartPointAfterSleepWakeUp
StartPointAfterSleepWakeUp

;設置存儲相關寄存器的程序
  ;SMRDATA中涉及的值請參考memcfg.inc程序
   ldr r0,=SMRDATA
ldr r1,=BWSCON ;BWSCON地址
add r2, r0, #52 ;SMRDATA結束地址

0
ldr r3, [r0], #4
str r3, [r1], #4
cmp r2, r0
bne %B0

      ;初始化堆棧
bl InitStacks

   ; 設置缺省中斷處理函數
ldr r0,=HandleIRQ    ;This routine is needed
ldr r1,=IsrIRQ    ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c
str r1,[r0]

;將數據段拷貝到RAM中,將ZI數據段清零,跳入C語言的main函數執行。

;If main() is used, the variable initialization will be done in __main().
[

NOT:USE_MAIN
      ;Copy and paste RW data/zero initialized data
LDR    r0, =|Image$$RO$$Limit| ; Get pointer to ROM data
LDR    r1, =|Image$$RW$$Base|  ; and RAM copy
LDR    r3, =|Image$$ZI$$Base|

;Zero init base => top of initialised data
CMP    r0, r1    ; Check that they are different
BEQ    %F2
1
CMP    r1, r3    ; Copy init data
LDRCC r2, [r0], #4 ;--> LDRCC r2, [r0] + ADD r0, r0, #4
STRCC r2, [r1], #4 ;--> STRCC r2, [r1] + ADD r1, r1, #4
BCC    %B1
2
LDR    r1, =|Image$$ZI$$Limit| ; Top of zero init segment
MOV    r2, #0
3
CMP    r3, r1    ; Zero init
STRCC r2, [r3], #4
BCC    %B3
]

[

NOT:THUMBCODE
      bl Main       ;Don't use main() because ......
      b .
]

[ THUMBCODE       ;for start-up code for Thumb mode
      orr lr,pc,#1
      bx lr
      CODE16
      bl Main       ;Don't use main() because ......
      b .
      CODE32
]

;初始化各模式下的堆棧指針

InitStacks
;Don't use DRAM,such as stmfd,ldmfd......
;SVCstack is initialized before
;Under toolkit ver 2.5, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'
mrs r0,cpsr
bic r0,r0,#MODEMASK
orr r1,r0,#UNDEFMODE|NOINT
msr cpsr_cxsf,r1       ;UndefMode
ldr sp,=UndefStack       ; UndefStack=0x33FF_5C00

orr r1,r0,#ABORTMODE|NOINT
msr cpsr_cxsf,r1       ;AbortMode
ldr sp,=AbortStack       ; AbortStack=0x33FF_6000

orr r1,r0,#IRQMODE|NOINT
msr cpsr_cxsf,r1       ;IRQMode
ldr sp,=IRQStack       ; IRQStack=0x33FF_7000

orr r1,r0,#FIQMODE|NOINT
msr cpsr_cxsf,r1       ;FIQMode
ldr sp,=FIQStack       ; FIQStack=0x33FF_8000

bic r0,r0,#MODEMASK|NOINT
orr r1,r0,#SVCMODE
msr cpsr_cxsf,r1       ;SVCMode
ldr sp,=SVCStack       ; SVCStack=0x33FF_5800

;USER mode has not be initialized.

mov pc,lr
;The LR register won't be valid if the current mode is not SVC mode.

;=====================================================================
; 時鐘測試
; Assemble code, because VSYNC time is very short
;=====================================================================
EXPORT CLKDIV124
EXPORT CLKDIV144

CLKDIV124

ldr    r0, = CLKDIVN
ldr    r1, = 0x3       ; 0x3 = 1:2:4
str    r1, [r0]
;延時時鐘穩定
nop
nop
nop
nop
nop

ldr    r0, = REFRESH
ldr    r1, [r0]
bic       r1, r1, #0xff
bic       r1, r1, #(0x7<<8)
orr       r1, r1, #0x470 ; REFCNT135
str    r1, [r0]
nop
nop
nop
nop
nop
mov    pc, lr

CLKDIV144
ldr    r0, = CLKDIVN
ldr    r1, = 0x4       ; 0x4 = 1:4:4
str    r1, [r0]
;延時時鐘穩定
nop
nop
nop
nop
nop

ldr    r0, = REFRESH
ldr    r1, [r0]
bic       r1, r1, #0xff
bic       r1, r1, #(0x7<<8)
orr       r1, r1, #0x630 ; REFCNT675 - 1520
str    r1, [r0]
nop
nop
nop
nop
nop
mov    pc, lr

LTORG

SMRDATA DATA
;存儲器控制寄存器的定義區
; 存儲器訪問周期參數
; The memory settings is  safe parameters even at HCLK=75Mhz.
; SDRAM refresh period is for HCLK<=75Mhz.

DCD (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))
DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC)) ;GCS0
DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC)) ;GCS1
DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC)) ;GCS2
DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC)) ;GCS3
DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC)) ;GCS4
DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC)) ;GCS5
DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN)) ;GCS6
DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN)) ;GCS7
DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)

DCD 0x32       ;SCLK power saving mode, BANKSIZE 128M/128M

DCD 0x30       ;MRSR6 CL=3clk
DCD 0x30       ;MRSR7 CL=3clk

ALIGN

AREA RamData, DATA, READWRITE

^ _ISR_STARTADDRESS       ; _ISR_STARTADDRESS=0x33FF_FF00
HandleReset    # 4
HandleUndef    # 4
HandleSWI       # 4
HandlePabort # 4
HandleDabort # 4
HandleReserved  # 4
HandleIRQ       # 4
HandleFIQ       # 4

;不要使用標簽'IntVectorTable',
;The value of IntVectorTable is different with the address you think it may be.
;IntVectorTable
;@0x33FF_FF20
HandleEINT0       # 4
HandleEINT1       # 4
HandleEINT2       # 4
HandleEINT3       # 4
HandleEINT4_7 # 4

HandleEINT8_23 # 4
HandleCAM       # 4       ; Added for 2440.
HandleBATFLT # 4
HandleTICK       # 4
HandleWDT       # 4

HandleTIMER0    # 4
HandleTIMER1    # 4
HandleTIMER2    # 4
HandleTIMER3    # 4
HandleTIMER4    # 4

HandleUART2    # 4
;@0x33FF_FF60
HandleLCD       # 4
HandleDMA0       # 4
HandleDMA1       # 4
HandleDMA2       # 4

HandleDMA3       # 4
HandleMMC       # 4
HandleSPI0       # 4
HandleUART1       # 4
HandleNFCON       # 4       ; Added for 2440.

HandleUSBD       # 4
HandleUSBH       # 4
HandleIIC       # 4
HandleUART0    # 4
HandleSPI1       # 4

HandleRTC       # 4
HandleADC       # 4
;@0x33FF_FFA0
END

轉載自阿吳網志|Awu's Website

3C2440啟動代碼注釋

相關文章

網友評論

廠商推薦

相關視頻